Script Request - AI Spotting

[trooper543]

Hi there all

I was wondering if anybody in the community has a script that will allow an AI soldier be a spotter?

What i would like to do is have AI soldiers that acts as a spotter's within different groups, that when they spot heavy armour / large groups that they will relay the information back to the player (who is in a different group) by marking the map as well as when the make contact with the enemy.

The main aim is to ensure info is passed back to the player so that the player can co ordinate his attack with the info

Any help and assistance will be very much appreciated

thanks

[Mandoble]

First, with a presence trigger placed where the spotter is, and with a range equivalent to normal visual range would be enough to get the list of units that the spotter might "see" (you may create this trigger dinamically and keep moving it to spotter position every a pair of seconds in a loop, for example). Now you only need to use knowsAbout command to check how much the spotter knows about every unit into the trigger list. you might set a minimum knowsabout level to mark the position of a vehicne in the map. For example, with 1 you might mark position, above 1 you mark direction and type of unit too.

[trooper543]

@ Mandoble

Thanks you so much for the response

Sorry to sound like idiot but where would i start ? Sorry just that i am not a scripter

I will check out the knowabout command

thanks

[Mandoble]

Hope this is easy to follow

Code: [Select]

// spotter.sqf
// res = [spotterunit]execVM"spotter.sqf"

// Looking for EAST units
_spotter = _this select 0;
_maxrange = 1200;
_trigger = createTrigger ["EmptyDetector", getPos vehicle _spotter];
_trigger setTriggerActivation ["EAST", "PRESENT", false];
_trigger setTriggerArea [_maxrange, _maxrange, 0, false];
_trigger setTriggerType "NONE";
_trigger setTriggerStatements ["this", "", ""];
_trigger setTriggerTimeout [0, 0, 0, false ];
// The trigger is created, its list will contain any EAST unit or vehicle present and closer than 1200m to its center

while {alive _spotter} do
{
   // Trigger is placed at spotter (or spotter vehicle) postion
   _trigger setPos getPos vehicle _spotter;

   // We wait a second to make sure the list of the trigger is correctly updated after the change of position
   Sleep 1;

   // Now the list is examined, looking for units known by the spotter
   {
      if (_spotter knowsAbout _x > 0) then
      {
         hint format["Our spotter knows something about %1 which is at %2 heading to %3", _x, getPos _x, getDir _x];
      };
   } forEach list _trigger;
   Sleep 3;
};

deleteVehicle _trigger;


[trooper543]

@ mandabole

Once again thanks you ever so much !! It is really appreciated

So i just call the script in the spotter units int?

[Mandoble]

You may create a init.sqf file, which is automatically executed at mission startup and inside:

Code: [Select]

//init.sqf
[spotterunitname]execVM"spotter.sqf";


[trooper543]

@Mandoble

Thanks once again for the script and the help it is very much appreciated.

i setup a unit called spotter 1 put the script and init script in the mission folder and i get an error message saying error line 12

have i done something wrong?

thanks

[Mandoble]

lol, sorry _spotter = _this select 1; should be _spotter = _this select 0;
Already corrected above.

[trooper543]

@ Mandoble

Sir, you are a gentlemen and a scholar!! and i again thank you

[LeeHunt]

this is a great idea! i was looking for something similar.  i'll test it out when i can but i think this should also be a Resource for ofpec...

[Tajin]

Haven't messed around with that command yet, but I believe it could be used for very much the same thing, just without triggers.:

http://community.bistudio.com/wiki/nearTargets

[Mandoble]

Yes, nearTargets is also an option. Problem (or advantage) is that all data comming from it is "perceived".